StockFetcher Forums · Filter Exchange · JUST WONDERING.....<< 1 2 3 >>Post Follow-up
chetron
2,817 posts
msg #67122
- Ignore chetron
modified		 9/9/2008 11:05:42 PM

WORK IN PROGRESS....


Fetcher[

/* ALFs NEW Range Contraction/Expansion Scan Filter */
/* AS CHETRON UNDERSTANDS IT */
/* THE DOJI AND AN OSCILLATOR AT AN EXTREME FILTER */

/* TACHIKAWA */

SET{VHH21,COUNT(HIGH 2 DAY AGO BELOW HIGH 1 DAY AGO,1)}
SET{VHH10,COUNT(HIGH BELOW HIGH 1 DAY AGO,1)}
SET{VHH3,VHH21 * VHH10}

SET{VLL21,COUNT(LOW 2 DAY AGO ABOVE LOW 1 DAY AGO,1)}
SET{VLL10,COUNT(LOW ABOVE LOW 1 DAY AGO,1)}
SET{VLL3,VLL21 * VLL10}

SET{VHH8,COUNT(HIGH 1 DAY AGO ABOVE HIGH 5 DAY HIGH 2 DAY AGO,1)}
SET{VLL8,COUNT(LOW 1 DAY AGO BELOW LOW 5 DAY LOW 2 DAY AGO ,1)}

SET{HIHI,VHH3 * VHH8}
SET{LOLO,VLL3 * VLL8}

DRAW HIHI
DRAW LOLO

SET{VAR1,COUNT(HIGH ABOVE HIGH 5 DAY HIGH 1 DAY AGO,1)}
SET{VAR2,COUNT(LOW BELOW LOW 5 DAY LOW 1 DAY AGO,1)}

SET{PICKS,VAR1 + VAR2}

/* NEW Range Contraction/Expansion Scan Filter */

/* Doji (H/L Rng above .20 w/Candle Body less than 30% of H/L Rng) */
set{HiLoRng, High - Low}
set{ClOpRng, abs(Close minus Open)}
set{ClOp_HiLo_ratio, ClOpRng / HiLoRng}
set{Range, count(HiLoRng is above .20, 1)}
set{Body, count(ClOp_HiLo_ratio is less than .30, 1)}
set{doji, Range * Body}

/* One Day Reversal (ODR) --> 5 Day H/L w/Up or Down Close Above/Below 50% Day Position */
/* ODR 50% Day Position Calculation */
set{HLrng, High - Low}
set{HLrng50, HLrng * .50}
set{DP50, Low + HLrng50}

/* ODR UP */
set{5daylo, count(Low reached a new 5 day Low, 1)}
set{ODR_UpClo, count(Close is above DP50, 1)}
set{ODR_Up, 5daylo * ODR_UpClo}

/* ODR DOWN */
set{5dayhi, count(High reached a new 5 day High, 1 )}
set{ODR_DwnClo, count(Close is below DP50, 1)}
set{ODR_Dwn, 5dayhi * ODR_DwnClo}

/* ODR UP or DOWN */
set{ODR_upORdwn, ODR_Up + ODR_Dwn}

/* PatternFetcher */
set{Do_Ji, doji * 1}
set{ODR_UD, ODR_upORdwn * 1}

/* 20 Day High/Low Breakout Check */

/* 20 day HIGH */
set{20dayhi, count(High reached a new 20 day High, 1 )}
/* 20 day LOW */
set{20daylo, count(Low reached a new 20 day Low, 1)}

/* 20 day HIGH or LOW */
set{20day_hiORlo, 20dayhi + 20daylo }

/* Columns Trend Strength */
add column separator
add column separator
add column 20day_hiORlo {20hilo}
ADD COLUMN HIHI
ADD COLUMN LOLO
add column separator
add column separator
add column WILLIAMS %R(2) {BILLY2}
add column separator
add column Slow Stochastic(7,10) Fast %K {%K.7}
add column separator
add column RSI(2) {rsi2}
add column separator

/* Columns (Patterns) */
add column separator
aadd column separator
add column ODR_upORdwn {ODR}
add column separator
add column separator

/* Daily Pivot Numbers */
add column separator
add column PP
add column R1
add column R2
add column S1
add column S2
add column separator

/* Indicators MAs */
draw DMA(3,3)
draw EMA(10)
draw EMA(30)
draw EMA(150)

draw RSI(2)
draw RSI(2) line at 10
draw RSI(2) line at 65
draw RSI(2) line at 90

draw Slow Stochastic(7,10) Fast %K
draw Slow Stochastic(7,10) Fast %K line at 20
draw Slow Stochastic(7,10) Fast %K line at 80
draw Slow Stochastic(7,10) Slow %D

VOLUME ABOVE 100000
DOJI > .5

chart-time is 44 days

]




ORB............

Fetcher[

/* PRICE PATTERNS */

/* Shark-32 (shark) --> (2 Consecutive Inside Days) */
set{IDhi_2, count(High 1 day ago is below High 2 days ago, 1)}
set{IDlo_2, count(Low 1 day ago is above Low 2 days ago, 1)}
set{IDhilo_2, IDhi_2 * IDlo_2}

set{IDhi_1, count(High is below High 1 day ago, 1)}
set{IDlo_1, count(Low is above Low 1 day ago, 1)}
set{IDhilo_1, IDhi_1 * IDlo_1}

set{ID21, IDhilo_2 * IDhilo_1}

/* --------------------------------------------- */

/* IDs (...id) (Inside Days -> H/L Range inside H/L Range 1 day ago) */
set{IDhi, count(High below High 1 day ago, 1)}
set{IDlo, count(Low above Low 1 day ago, 1)}
set{ID, IDhi * IDlo}

/* --------------------------------------------- */

/* NR7s (nr.7) (Narrowist Range of the last 7 days) */
set{NR7, count(Day Point Range reached a new 7 day Low, 1)}

/* ---------------------------------------------- */

/* NR4s (nr.4) (Narrowist Range of the last 4 days) */
set{NR4, count(Day Point Range reached a new 4 day Low, 1)}

SET{VAR1,ID * NR4}
SET{VAR2,VAR1 + NR7}

/* ----------------------------------------------- */

/* Gaps (gap) (Unfilled Gaps) */
set{Gapup, count(Low is above High 1 day ago, 1)}
set{Gapdwn, count(High is below Low 1 day ago, 1)}
set{GapupORGapdwn, Gapup + Gapdwn}

/* ------------------------------------------------ */

/* Crable Hooks (hook) */

/* BULL Hook --> (Open above prev. High with Close below prev. Close & Range < prev. day's Range) */

set{RangeDWN, High - Low}
set{RangeDWN_1, High 1 day ago - Low 1 day ago}

set{RangeHookDWN, count(RangeDWN < RangeDWN_1, 1)}
set{OpenHookDWN, count(Open above High 1 day ago, 1)}
set{CloseHookDWN, count(Close below Close 1 day ago, 1)}

set{Hook_DWN_A, RangeHookDWN * OpenHookDWN}
set{BullHookDWN, Hook_DWN_A * CloseHookDWN}


/* BEAR Hook --> (Open below prev. Low with Close above prev. Close & Range < prev. day's Range) */
set{RangeUP, High - Low}
set{RangeUP_1, High 1 day ago - Low 1 day ago}

set{RangeHookUP, count(RangeUP < RangeUP_1, 1)}
set{OpenHookUP, count(Open below Low 1 day ago, 1)}
set{CloseHookUP, count(Close above Close 1 day ago, 1)}

set{Hook_UP_A, RangeHookUP * OpenHookUP}
set{BearHookUP, Hook_UP_A * CloseHookUP}


/* BearHookUP OR BullHookDOWN */
set{BearHookUPorBullHookDOWN, BearHookUP + BullHookDWN}

/* ------------------------------------------------- */

/* Crable Opening Range Breakout (stretch)
(Average of the differences between the Open each day and the closest extreme (ie. H / L) to the Open each day over the previous 10 days...the stretch is then add. / subt. to today's Open giving price levels for either a Long / Short entry */

/* ORB STRETCH Calculations */
set{diff1, abs(Open minus High)}
set{diff2, abs(Open minus Low)}
set{stretch_diff, min(diff1,diff2)}

set{stretch_sum, sum(stretch_diff,10)}
set{stretch_avg10, stretch_sum / 10}


/* Profit Target (profit) -> (An amount based on 66% of a 10 day average of the H / L Range that when add. / subt. to entry gives a theoretical profit target ) */

/* Profit Target Calculations */
set{HiLo_rng, High minus Low}
set{HiLo_rngsum, sum(HiLo_rng,10)}
set{HiLo_rngavg, HiLo_rngsum / 10}

set{ProfTarget_66, HiLo_rngavg * .66}

/* ----------------------------------------------- */

/* TECHNICAL INDICATORS */

/* Defining myOSC(3,8) Indicator */
set{myOSC, EMA(3) - EMA(8)}

/* Defining trend(13) of myOSC(3,8) Indicator */
set{myOSCtrend, CEMA(myOSC,13)}

/* COLUMNS */


/* Columns (Patterns) */
add column separator
add column separator
add column ID {...id}
add column NR7 {nr.7}
add column NR4 {nr.4}
add column GapupORGapdwn {Gap}
add column separator
add column separator
add column BearHookUPorBullHookDOWN {hook}

/* Crabel ORB stuff */
add column stretch_avg10{stretch}
add column ProfTarget_66{Profit}
add column separator
add column separator

/* ------------------------------------ */

/* INDICATORS */

draw myOSC
draw myOSC line at 0
draw CEMA(myOSC,13)

VAR2 ABOVE .5

CLOSE ABOVE .1
VOLUME ABOVE 100000
]
alf44
2,025 posts
msg #67124
- Ignore alf44		 9/10/2008 12:07:11 AM

First of all, that's not the most current version !

Secondly, you've changed the "filter"...that's not the way it was posted in my thread...and not the way I use it !

Thirdly, don't "WONDER" too hard...you might hurt yourself !!! lol


Regards,

alf44
alf44
2,025 posts
msg #67125
- Ignore alf44
modified		 9/10/2008 12:12:59 AM

...by all means though...keep "WONDERING"...and please keep the Forum informed of your findings !
johnpaulca
12,036 posts
msg #67134
- Ignore johnpaulca		 9/10/2008 9:00:57 AM

Hey Chet...I was WONDERING how you trade that filter.
chetron
2,817 posts
msg #67136
- Ignore chetron		 9/10/2008 9:14:23 AM



i am trying to draw a "chart-o-gram" to express alfs statement,

"
When dojis come at oscillator extremes they can be very powerful Reversal Signals ! When dojis occur at those oscillator extremes they are typically referred to as...well, Dojis (of course)...Stars...Hammers...Inverted Hammers etc...

"
alf44
2,025 posts
msg #67165
- Ignore alf44
modified		 9/11/2008 11:16:59 AM

...since my words are being cut and pasted into this thread...by people other than me...

...thought I'd cut and paste a few myself !

----------------------------------------------------------------

"This particular "filter" (ie. Range Contraction/Expansion Filter) is NOT a filter in the usual sense of the term. It doesn't identify Oscillator Overbought or Oversold conditions or Signal Line crosses or Moving Average Crossovers. It JUST focuses on PRICE !

Specifically...PRICE ACTION (and patterns) !!!


It simply makes me aware of certain Market phenomena ! "

-------------------------

"Any ONE of these patterns is a subject unto itself !

Each requires a different approach and a different set of trading rules !"

-------------------------

"It's definitely NOT for everybody !

It requires abilities and expertise that most are either unaware of...OR...are unwilling to learn ! "

-------------------------


Regards,

alf44
chetron
2,817 posts
msg #67302
- Ignore chetron		 9/15/2008 5:00:16 PM

work in progress


Fetcher[



/* TRO STAT SCAN - TRAVEL GUIDE - POCKET EDITION in cents */
/* with chetronisms */

/* tachikawa */

set{xRange, high - low}
set{AvgRng, cma(xRange,5) }

and add column separator
and add column separator

ADD COLUMN OPEN

set{HiOp, High - Open }
set{RunPCT, HiOp}
set{AvgRun5, cma(RunPCT,5) }
set{AvgRun20, cma(RunPCT,20) }

SET{RUNMIN,MIN(AVGRUN5,AVGRUN20)}
SET{VAR1,RUNMIN 1 DAY AGO}
SET{TRUN,OPEN + VAR1}
ADD COLUMN TRUN

add column high

set{HiCl, High - Close }
set{PBPCT, HiCl}
set{AvgPB5, cma(PBPCT,5) }
set{AvgPB20, cma(PBPCT,20) }

SET{PBMIN,MIN(AVGPB5,AVGPB20)}
SET{VAR2,PBMIN 1 DAY AGO}
SET{TPB,TRUN - VAR2}
ADD COLUMN TPB

set{OpLo, Open - low}
set{DropPCT, OpLo }
set{AvgDrop5, cma(DropPCT,5) }
set{AvgDrop20, cma(DropPCT,20) }

SET{DROPMIN,MIN(AvgDrop5,AvgDrop20)}
SET{VAR4,DROPMIN 1 DAY AGO}
SET{TDROP,OPEN - VAR4}
ADD COLUMN TDROP

add column low

set{ClLo, Close - low }
set{BouncePCT, ClLo }
set{AvgBounce5, cma(BouncePCT,5) }
set{AvgBounce20, cma(BouncePCT,20) }

SET{BOUNCEMIN,MIN(AvgBounce5,AvgBounce20)}
SET{VAR3,BOUNCEMIN 1 DAY AGO}
SET{TBOUNCE,TDROP + VAR3}
ADD COLUMN TBOUNCE

add column close

and add column separator
and add column separator


set{Green, count( close > open , 100)}

set{B10A, count(RunPCT > .10 , 100)}

set{A10A, count(RunPCT > .10 , 1)}
set{chg, sum( A10A - A10A 1 day ago ,5)}

/* SELECTION CRITERIA */

symlist(abk,cog,exm,JRCC,HOLX,rdn,AAPL,STSA,vrx)

sort column 1 Ascending






]
chetron
2,817 posts
msg #67532
- Ignore chetron		 9/19/2008 8:35:15 PM

FLAGPOLES??????????????


Fetcher[

/* TACHIKAWA */

SET{VAR1,HIGH 1 DAY AGO}
SET{VAR2,LOW 1 DAY AGO}

SET{buy_ME,COUNT(LOW > VAR1,8)}
SET{short_ME,COUNT(HIGH < VAR2,8)}
SET{TRIG_ME,SHORT_ME + BUY_ME}

ADD COLUMN SHORT_ME
ADD COLUMN BUY_ME

DRAW BUY_ME ON PLOT SHORT_ME
draw avgvol(21)

TRIG_me > .5
CLOSE ABOVE 1.4
VOLUME > 1000000

sort column 4 descending

]
chetron
2,817 posts
msg #68649
- Ignore chetron		 10/21/2008 7:53:45 PM

i am still wondering.....



Fetcher[

set{vh3,high 3 day ago}
set{vh2,high 2 day ago}
set{vh1,high 1 day ago}

set{var2a,vh2 - vh1}
set{var3a,vh3 - vh2}

set{var1,high - var2a}
set{var2, vh1 - var3a}

draw var1 on plot price
draw var2 on plot price

var1 below var2
high below var1
high below var2
close above .1
volume above 10000000


]
chetron
2,817 posts
msg #69442
- Ignore chetron
modified		 11/30/2008 10:04:55 PM

HOW ABOUT.....

Fetcher[

/* looking for buying at close and selling to the next day pop */

SET{VAR1,HIGH + LOW}
SET{VAR2,VAR1 / 2}

SET{TRIP1A,COUNT(CLOSE < VAR2,1)}
SET{TRIP1B,COUNT(LOW > PARABOLIC SARS,1)}
SET{TRIP1C,COUNT(RSI(2) > 94,1)}
SET{TRIP1D,TRIP1A * TRIP1B}
SET{TRIP1,TRIP1D * TRIP1C}

SET{TRIP2A,COUNT(OPEN > VAR2,1)}
SET{TRIP2B,COUNT(HIGH < PARABOLIC SARS,1)}
SET{TRIP2C,COUNT(RSI(2) < 6,1)}
SET{TRIP2D,TRIP2A * TRIP2B}
SET{TRIP2,TRIP2D * TRIP2C}

SET{BUY_ME,TRIP1 + TRIP2}

BUY_ME > .5

DRAW PARABOLIC SARS
DO NOT DRAW EMA(100)
DO NOT DRAW BUY_ME
CHART-TIME 22 DAY

OPEN < CLOSE
OPEN 1 DAY AGO < CLOSE 1 DAY AGO

]




THIS LOOKS LIKE ANOTHER LONG....


Fetcher[



/* looking for LONG at close and SELL to the next day pop */

SET{VAR1,HIGH + LOW}
SET{VAR2,VAR1 / 2}

SET{TRIP1A,COUNT(OPEN < VAR2,1)}
SET{TRIP1B,COUNT(LOW > PARABOLIC SARS,1)}
SET{TRIP1C,COUNT(RSI(2) > 94,1)}
SET{TRIP1D,TRIP1A * TRIP1B}
SET{TRIP1,TRIP1D * TRIP1C}

SET{TRIP2A,COUNT(CLOSE > VAR2,1)}
SET{TRIP2B,COUNT(HIGH < PARABOLIC SARS,1)}
SET{TRIP2C,COUNT(RSI(2) < 6,1)}
SET{TRIP2D,TRIP2A * TRIP2B}
SET{TRIP2,TRIP2D * TRIP2C}

SET{LONG_ME,TRIP1 + TRIP2}

LONG_ME > .5

DRAW PARABOLIC SARS
DO NOT DRAW EMA(100)
DO NOT DRAW LONG_ME
CHART-TIME 22 DAY

OPEN > CLOSE
OPEN 1 DAY AGO > CLOSE 1 DAY AGO


]
StockFetcher Forums · Filter Exchange · JUST WONDERING.....<< 1 2 3 >>Post Follow-up

StockFetcher Tools
Filter Editor
My Filters
Watch Lists
Chart+
Find Similar Stocks
Shared Lists
Popular Resources
StockFetcher Forums
Indicator List
Filter Phrases
Examples
Site Search
Sector/Industry List
Usage Guide
Support
Contact Us
Support Home

Subscriber
Subscriber Benefits
Settings
Chart
Results
MyFilters
*** Disclaimer *** StockFetcher.com does not endorse or suggest any of the securities which are returned in any of the searches or filters. They are provided purely for informational and research purposes. StockFetcher.com does not recommend particular securities. StockFetcher.com, Vestyl Software, L.L.C. and involved content providers shall not be liable for any errors or delays in the content, or for any actions taken based on the content.


Copyright 2022 - Vestyl Software L.L.C.•Terms of Service | License | Questions or comments? Contact Us
EOD Data sources: DDFPlus & CSI Data Quotes delayed during active market hours. Delay times are at least 15 mins for NASDAQ, 20 mins for NYSE and Amex. Delayed intraday data provided by DDFPlus


This site is protected by reCAPTCHA and the Google Privacy Policy and Terms of Service apply.